[Gramática usada para criar o PAPEL 3.0
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2011

[Padrões indicadores de relações de Causa

> terminais.txt
> uteis.txt

[ ------- CAUSADOR ------- ]

PADRAO_CAUSADOR ::= VERBO_CAUSA_PP <&> DE_POR_EM
PADRAO_CAUSADOR ::= VERBO_CAUSA_PP <&> CONJ <&> <?> <&> DE_POR_EM
PADRAO_CAUSADOR ::= VERBO_CAUSA_PP <&> MANEIRA_DE_CAUSAR <&> DE_POR_EM

DEVIDO_A ::= DEVIDO <&> A
DEVIDO_A ::= DEVIDO <&> A <&> TERCEIRO <&> DE
DEVIDO_A ::= DEVIDO <&> MANEIRA_DE_CAUSAR <&> A <&>

MANEIRA_DE_CAUSAR ::= ADVERBIO
[MANEIRA_DE_CAUSAR ::= <>
[TERCEIRO ::= <>

MODIFICADOR_CAUSADOR ::= MODIFICADOR_NOME

[ ------- RESULTADO ------- ]

PADRAO_RESULTADO ::= VERBO_RESULTADO_PRES
PADRAO_RESULTADO ::= VERBO_RESULTADO_PRES <&> MANEIRA_DE_RESULTAR
PADRAO_RESULTADO ::= MANEIRA_DE_RESULTAR <&> VERBO_RESULTADO_PRES
PADRAO_RESULTADO ::= VERBO_RESULTADO_PRES <&> CONJ <&> <?>

MANEIRA_DE_RESULTAR ::= ADVERBIO
MODIFICADOR_RESULTADO ::= MODIFICADOR_NOME
MODIFICADOR_RESULTADO_ACCAO ::= MODIFICADOR_NOME

[------------------------- Outros indicadores --------------------]

POR_ACCAO_DE ::= PDET <&> ACTO_ACCAO_EFEITO <&> DE
POR_ACCAO_DE ::= PDET <&> ACTO_ACCAO_EFEITO <&> CONJ <&> ACTO_ACCAO_EFEITO <&> DE
POR_ACCAO_DE ::= PDET <&> ACTO_ACCAO_EFEITO <&> CONJ <&> <?> <&> DE

TER_COMO_CAUSA ::= por <&> INST_CAUSADOR <&> DE
TER_COMO_CAUSA ::= CUJO <&> INST_CAUSADOR <&> VERBO_SER_PRES
TER_COMO_CAUSA ::= que <&> TER_COMO <&> INST_CAUSADOR
TER_COMO_CAUSA ::= que <&> VERBO_POSSIBILIDADE <&> TER_COMO <&> INST_CAUSADOR
TER_COMO_CAUSA ::= em <&> INST_RESULTADO <&> DE

TER_COMO_RESULTADO ::= CUJO <&> INST_RESULTADO <&> VERBO_SER_PRES
TER_COMO_RESULTADO ::= que <&> TER_COMO <&> INST_RESULTADO

INST_CAUSADOR ::= causador
INST_CAUSADOR ::= causadora
INST_CAUSADOR ::= causadores
INST_CAUSADOR ::= causadoras
INST_CAUSADOR ::= originador
INST_CAUSADOR ::= originadora
INST_CAUSADOR ::= originadores
INST_CAUSADOR ::= originadoras
INST_CAUSADOR ::= provocador
INST_CAUSADOR ::= provocadora
INST_CAUSADOR ::= provocadores
INST_CAUSADOR ::= provocadoras
INST_CAUSADOR ::= gerador
INST_CAUSADOR ::= geradora
INST_CAUSADOR ::= geradores
INST_CAUSADOR ::= geradoras

INST_CAUSADOR ::= causa
INST_CAUSADOR ::= origem

INST_RESULTADO ::= resultado
INST_RESULTADO ::= manifestação
INST_RESULTADO ::= consequência

RESULTANTE ::= resultante
RESULTANTE ::= consequente

[ ----- HIPERONIMIA ------ ]

PADRAO_HIPER ::= HIPERONIMO_DE
PADRAO_HIPER ::= MODIFICADOR_HIPERONIMO <&> HIPERONIMO_DE
PADRAO_HIPER ::= HIPERONIMO_DE <&> MODIFICADOR_HIPERONIMO


[---- Negacao -----]

-100 # PADRAO ::= NAO <&> PADRAO <&> ENUM_NAO_CAUS
-100 # PADRAO ::= NAO <&> é <&> PADRAO_CAUSADOR <&> ENUM_NAO_CAUS

ENUM_NAO_CAUS ::= SN_NAO_CAUS <&> VIRG <&> ENUM_NAO_CAUS
ENUM_NAO_CAUS ::= SN_NAO_CAUS <&> CONJ <&> SN_NAO_CAUS
ENUM_NAO_CAUS ::= SN_NAO_CAUS

SN_NAO_CAUS ::= NAO_CAUSADOR
SN_NAO_CAUS ::= PRE_RELACIONADO <&> SN_NAO_CAUS
SN_NAO_CAUS ::= DET <&> SN_NAO_CAUS
SN_NAO_CAUS ::= S_PREP <&> SN_NAO_CAUS
SN_NAO_CAUS ::= PRON_POSS <&> NAO_CAUSADOR
SN_NAO_CAUS ::= PRON_PESS <&> NAO_CAUSADOR
SN_NAO_CAUS ::= MODIFICADOR_CAUSADOR <&> NAO_CAUSADOR

NAO_CAUSADOR ::= <?>


ENUM_NAO_RES ::= SN_NAO_RES <&> VIRG <&> ENUM_NAO_RES
ENUM_NAO_RES ::= SN_NAO_RES <&> CONJ <&> SN_NAO_RES
ENUM_NAO_RES ::= SN_NAO_RES

SN_NAO_RES ::= NAO_RESULTADO
SN_NAO_RES ::= PRE_RELACIONADO <&> NAO_RESULTADO
SN_NAO_RES ::= S_PREP <&> SN_NAO_RES
SN_NAO_RES ::= DET <&> SN_NAO_RES
SN_NAO_RES ::= PRON_POSS <&> NAO_RESULTADO
SN_NAO_RES ::= MODIFICADOR_RESULTADO <&> SN_NAO_RES

NAO_RESULTADO ::= <?>