[Gramática usada para criar o PAPEL 3.0
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2011

[Regras com construções úteis, como "entidades complexas" (e.g. "A de B") ou inícios de definição típicos de adjectivos ou advérbios.

> terminais.txt
> verbos.txt
> cabecas_vazias.txt

[Regra recursiva para garantir que a derivação é completa]
-10 # QUALQUERCOISA ::= <?> <&> QUALQUERCOISA
-10 # QUALQUERCOISA ::= <?>

PRE_RELACIONADO ::= VIRG <&> QUALQUERCOISA <&> VIRG
PRE_RELACIONADO ::= PONTUACAO

S_PREP ::= S_PREP <&> TERCEIRO <&> S_PREP
S_PREP ::= PREP <&> MESMO
S_PREP ::= PREP <&> se
S_PREP ::= PREP

REFERENTE_A ::= REFERENTE <&> A
REFERENTE_A ::= RELACIONADO <&> com
REFERENTE_A ::= REFERENTE <&> CONJ <&> <?> A
REFERENTE_A ::= RELACIONADO <&> CONJ <&> <?> <&> com
REFERENTE_A_QUEM ::= REFERENTE_A <&> QUE_QUEM

[nao funciona com o tokenizer do opennlp
DIZ_SE ::= diz-se <&> DE
DIZ_SE ::= diz-se <&> DE <&> QUE
DIZ_SE ::= diz-se <&> DE <&> QUALQUERCOISA <&> QUE
DIZ_SE ::= diz-se <&> PREP_DEM <&> QUE

[ ----- Inícios típicos de definições ---- ]

INICIO_DEF_ADJ ::= que
INICIO_DEF_ADJ ::= em
INICIO_DEF_ADJ ::= REFERENTE_A

INICIO_DEF_ADJ ::= DIZ_SE

INICIO_DEF_ADJ_SER ::= INICIO_DEF_ADJ <&> VERBO_SER_PRES
[muitas vezes omite-se o "é" no início
INICIO_DEF_ADJ_SER ::= <>

INICIO_DEF_ADJ_TER ::= INICIO_DEF_ADJ <&> tem




INICIO_DEF_ADV ::= de <&> MANEIRA
INICIO_DEF_ADV ::= por <&> MANEIRA
INICIO_DEF_ADV ::= com
INICIO_DEF_ADV ::= sem
INICIO_DEF_ADV ::= em
INICIO_DEF_ADV ::= como
INICIO_DEF_ADV ::= por <&> meio <&> de

[ ----- Hiperónimo modificado ----- ]

HIPERONIMO_MODIFICADO ::= HIPERONIMO_OU_VAZIO
HIPERONIMO_MODIFICADO ::= MODIFICADOR_HIPERONIMO <&> HIPERONIMO_OU_VAZIO
HIPERONIMO_MODIFICADO ::= HIPERONIMO_OU_VAZIO <&> MODIFICADOR_HIPERONIMO
HIPERONIMO_MODIFICADO ::= MODIFICADOR_HIPERONIMO <&> HIPERONIMO_OU_VAZIO <&> MODIFICADOR_HIPERONIMO

MODIFICADOR_HIPERONIMO ::= MODIFICADOR_NOME

[ ----- Entidade complexa, termos multipalavra ----- ]

ENTIDADE_COMPLEXA ::= <?>
ENTIDADE_COMPLEXA ::= <?> <&> DE <&> ENTIDADE_COMPLEXA
ENTIDADE_COMPLEXA ::= <?> <&> DE <&> DET <&> ENTIDADE_COMPLEXA
ENTIDADE_COMPLEXA ::= <?> <&> DE <&> PRON_POSS <&> ENTIDADE_COMPLEXA
ENTIDADE_COMPLEXA ::= <?> <&> DE <&> DET <&> MESMO <&> ENTIDADE_COMPLEXA
[ENTIDADE_COMPLEXA ::= <?> <&> DE <&> ENTIDADE_COMPLEXA <&> CONJ <&> DE <&> ENTIDADE_COMPLEXA

[estes sao mais dúbios..
[ENTIDADE_COMPLEXA ::= <?> <&> com <&> ENTIDADE_COMPLEXA
[ENTIDADE_COMPLEXA ::= <?> <&> A <&> ENTIDADE_COMPLEXA