[Gramática usada para criar o PAPEL 3.0
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2011

[Regras para a detecção de relações de Finalidade em definições de adjectivos

> ../terminais.txt
> ../uteis.txt
> ../verbos.txt
> ../padroes_finalidade.txt

[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO <&> QUALQUERCOISA
RAIZ ::= PADRAO

[------------------------- Padrões indicadores -------------------------]

PADRAO ::= PADRAO_FIN_PROP
PADRAO ::= PADRAO_FIN_ACC_PROP

PADRAO_FIN_PROP ::= PADRAO_USADO_PARA <&> ENUM_FINS_PROP
PADRAO_FIN_PROP ::= PADRAO_OBJECTIVO <&> ENUM_FINS_PROP

PADRAO_FIN_ACC_PROP ::= PADRAO_SERVIR_PARA <&> ENUM_FINS_ACC_PROP
PADRAO_FIN_ACC_PROP ::= PROPRIO <&> PARA <&> ENUM_FINS_ACC_PROP


[------------------------- Outras regras -------------------------]

ENUM_FINS_PROP ::= INCLUI_FINS <&> VIRG <&> ENUM_FINS_PROP
ENUM_FINS_PROP ::= INCLUI_FINS <&> CONJ <&> INCLUI_FINS
ENUM_FINS_PROP ::= INCLUI_FINS

ENUM_FINS_ACC_PROP ::= INCLUI_FIN_ACC <&> VIRG <&> ENUM_FINS_ACC_PROP
ENUM_FINS_ACC_PROP ::= INCLUI_FIN_ACC <&> CONJ <&> INCLUI_FIN_ACC
ENUM_FINS_ACC_PROP ::= INCLUI_FIN_ACC

[------------------------- Pré-relacionados -------------------------]

INCLUI_FINS ::= FAZ_SE_COM_ALGO_COM_PROPRIEDADE
INCLUI_FINS ::= PRE_RELACIONADO <&> FAZ_SE_COM_ALGO_COM_PROPRIEDADE
INCLUI_FINS ::= PARA <&> INCLUI_FINS
INCLUI_FINS ::= DET <&> FAZ_SE_COM_ALGO_COM_PROPRIEDADE
INCLUI_FINS ::= MESMO <&> FAZ_SE_COM_ALGO_COM_PROPRIEDADE
INCLUI_FINS ::= DET <&> MESMO <&> FAZ_SE_COM_ALGO_COM_PROPRIEDADE

INCLUI_FIN_ACC ::= FINALIDADE_DE_ALGO_COM_PROPRIEDADE
INCLUI_FIN_ACC ::= PRE_RELACIONADO <&> FINALIDADE_DE_ALGO_COM_PROPRIEDADE
INCLUI_FIN_ACC ::= PARA <&> FINALIDADE_DE_ALGO_COM_PROPRIEDADE

[------------------------- Relacionados -------------------------]

FAZ_SE_COM_ALGO_COM_PROPRIEDADE ::= ENTIDADE_COMPLEXA


FINALIDADE_DE_ALGO_COM_PROPRIEDADE ::= VERBO_INTERMEDIO_INF <&> PREP <&> ENTIDADE_COMPLEXA
FINALIDADE_DE_ALGO_COM_PROPRIEDADE ::= VERBO_INTERMEDIO_INF <&> <?>
FINALIDADE_DE_ALGO_COM_PROPRIEDADE ::= <?> <&> DET <&> ENTIDADE_COMPLEXA
FINALIDADE_DE_ALGO_COM_PROPRIEDADE ::= VERBO_INF
FINALIDADE_DE_ALGO_COM_PROPRIEDADE ::= <?>
FINALIDADE_DE_ALGO_COM_PROPRIEDADE ::= PRON_PESS <&> FINALIDADE_DE_ALGO_COM_PROPRIEDADE