[Gramática usada para criar o PAPEL 3.0
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2011

[Regras para a detecção de relações de Parte em definições de adjectivos

> ../terminais.txt
> ../uteis.txt
> ../padroes_parte.txt
> ../tipos_locais.txt

[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_INICIO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA

[------------------------- Padrões indicadores -------------------------]

PADRAO_INICIO ::= PADRAO_PARTE
PADRAO_INICIO ::= PADRAO_INCLUI

[que possui X
PADRAO_PARTE ::= INICIO_DEF_ADJ <&> PADRAO_INCLUI <&> ENUM_MEMBRO

[relativo ou pertencente a X
PADRAO_INCLUI ::= PADRAO_PERTENCA <&> ENUM_INCLUI
PADRAO_INCLUI ::= INICIO_DEF_ADJ <&> PADRAO_PERTENCA <&> ENUM_INCLUI
[que pertence a
PADRAO_INCLUI ::= INICIO_DEF_ADJ <&> VERBO_PERTENCER_PRES <&> A <&> ENUM_INCLUI
[que faz parte de
PADRAO_INCLUI ::= PADRAO_FAZ_PARTE <&> ENUM_INCLUI

[------------------------- Outras regras -------------------------]

ENUM_MEMBRO ::= SN_MEMBRO <&> VIRG <&> ENUM_MEMBRO
ENUM_MEMBRO ::= SN_MEMBRO <&> CONJ <&> SN_MEMBRO
ENUM_MEMBRO ::= SN_MEMBRO

SN_MEMBRO ::= MEMBRO_DE_ALGO_COM_PROPRIEDADE
SN_MEMBRO ::= PRE_RELACIONADO <&> SN_MEMBRO
SN_MEMBRO ::= DET <&> SN_MEMBRO
SN_MEMBRO ::= TUDO <&> SN_MEMBRO
SN_MEMBRO ::= PRON_POSS <&> SN_MEMBRO
SN_MEMBRO ::= ADJ_GENERICO <&> SN_MEMBRO

ENUM_INCLUI ::= SN_INCLUI <&> VIRG <&> ENUM_INCLUI
ENUM_INCLUI ::= SN_INCLUI <&> CONJ <&> SN_INCLUI
ENUM_INCLUI ::= SN_INCLUI

SN_INCLUI ::= INCLUI_ALGO_COM_PROPRIEDADE
50 # SN_INCLUI ::= CONJUNTO <&> DE_PLURAL <&> INCLUI_ALGO_COM_PROPRIEDADE
50 # SN_INCLUI ::= GRUPO <&> DE_PLURAL <&> INCLUI_ALGO_COM_PROPRIEDADE
50 # SN_INCLUI ::= CLASSE <&> DE_PLURAL <&> INCLUI_ALGO_COM_PROPRIEDADE
50 # SN_INCLUI ::= LOCAL <&> DE <&> INCLUI_ALGO_COM_PROPRIEDADE
SN_INCLUI ::= PRE_RELACIONADO <&> SN_INCLUI
SN_INCLUI ::= DET <&> SN_INCLUI
SN_INCLUI ::= TUDO <&> SN_INCLUI
SN_INCLUI ::= PRON_POSS <&> SN_INCLUI
SN_INCLUI ::= ADJ_GENERICO <&> SN_INCLUI

LOCAL ::= TIPO_LOCAL
LOCAL ::= TIPO_LOCAL <&> <?>

[--------------- Terminais --------------------]

S_PREP ::= PREP
S_PREP ::= PREP <&> MESMO


MEMBRO_DE_ALGO_COM_PROPRIEDADE ::= ENTIDADE_COMPLEXA
INCLUI_ALGO_COM_PROPRIEDADE ::= ENTIDADE_COMPLEXA