[Gramática usada para criar o PAPEL 3.0
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2011

[Regras para a detecção de relações Produtor (directa) em definições de adjectivos

> ../terminais.txt
> ../verbos.txt
> ../uteis.txt
> ../padroes_produtor.txt


[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_INICIO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA

[------------------------- Padrões indicadores -------------------------]

[só podem ocorrer no início da definição
PADRAO_INICIO ::= PADRAO_PROPRIEDADE

[diz-se do que é causado por X
PADRAO_PROPRIEDADE ::= INICIO_DEF_ADJ_SER <&> PADRAO_PRODUTOR <&> ENUM_PROP


[------------------------- Regras -------------------------]

ENUM_PROP ::= SN_PROP
ENUM_PROP ::= SN_PROP <&> VIRG <&> ENUM_PROP
ENUM_PROP ::= SN_PROP <&> CONJ <&> ENUM_PROP

SN_PROP ::= PRODUTOR_DE_ALGO_COM_PROPRIEDADE
SN_PROP ::= DET <&> SN_PROP
SN_PROP ::= DE_POR <&> SN_PROP
SN_PROP ::= QUAL <&> PRODUTOR_DE_ALGO_COM_PROPRIEDADE
SN_PROP ::= PRON_POSS <&> PRODUTOR_DE_ALGO_COM_PROPRIEDADE


[------------------------- Relacionados -------------------------]

PRODUTOR_DE_ALGO_COM_PROPRIEDADE ::= ENTIDADE_COMPLEXA