[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações de Causa (directa) em definições de nomes
[Permite ainda detectar também algumas relações de Hiperonímia

> ../terminais.txt
> ../verbos.txt
> ../uteis.txt
> ../padroes_causa.txt


[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_INICIO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA
RAIZ ::= QUALQUERCOISA <&> PADRAO
RAIZ ::= QUALQUERCOISA <&> PADRAO <&> QUALQUERCOISA

[------------------------- Padrões indicadores -------------------------]

[TODO: incorporar manifestação, resultante/resultado, reflexo?

[podem ocorrer em qualquer sítio na definição
PADRAO ::= PADRAO_CAUSADOR_A
PADRAO ::= PADRAO_CAUSADOR_C
PADRAO ::= PADRAO_CAUSADOR_D
PADRAO ::= PADRAO_CAUSADOR_E
PADRAO ::= PADRAO_PROP_CAUS_B

-100 # PADRAO ::= NAO <&> PADRAO <&> ENUM_NAO_CAUS
-100 # PADRAO ::= NAO <&> é <&> PADRAO_CAUSADOR <&> ENUM_NAO_CAUS

[só podem ocorrer no início da definição
PADRAO_INICIO ::= PADRAO_CAUSADOR_B
PADRAO_INICIO ::= PADRAO_CAUSADOR_D
PADRAO_INICIO ::= PADRAO_CAUSADOR_INICIO
PADRAO_INICIO ::= PADRAO_ACC_CAUS
PADRAO_INICIO ::= PADRAO_PROP_CAUS_A

[...causado por/pela... X - CAUSADOR_DE
100 # PADRAO_CAUSADOR_INICIO ::= PADRAO_HIPER <&> PADRAO_CAUSADOR <&> ENUM_CAUS

PADRAO_CAUSADOR_A ::= PADRAO_CAUSADOR <&> ENUM_CAUS

[resultado de X
PADRAO_CAUSADOR_B ::= INST_RESULTADO <&> DE <&> ENUM_CAUS
PADRAO_CAUSADOR_B ::= DET <&> PADRAO_CAUSADOR_B

[por causa de X/cuja causa é X/tem por causa X
PADRAO_CAUSADOR_C ::= TER_COMO_CAUSA <&> ENUM_CAUS

[devido a X - CAUSADOR_DE
PADRAO_CAUSADOR_D ::= DEVIDO_A <&> ENUM_CAUS
PADRAO_CAUSADOR_D ::= DEVIDO_A <&> ACTO_ACCAO_EFEITO <&> DE <&> ENUM_CAUS
[se MANEIRA e TERCEIRO pudessem ser vazios, esta regra substituia as anteriores, mas entra em ciclo...
[PADRAO_CAUSADOR_D ::= devido <&> MANEIRA_DE_CAUSAR <&> A <&> TERCEIRO <&> ENUM_CAUS

PADRAO_CAUSADOR_E ::= POR_ACCAO_DE <&> ENUM_CAUS

[efeito de X - ACCAO_QUE_CAUSA
PADRAO_ACC_CAUS ::= ACTO_ACCAO_EFEITO <&> DE <&> ENUM_ACC_CAUS
PADRAO_ACC_CAUS ::= ACTO_ACCAO_EFEITO <&> CONJ <&> ACTO_ACCAO_EFEITO <&> DE <&> ENUM_ACC_CAUS
[2012.08.06: acto de tornar oficial
PADRAO_ACC_CAUS ::= ACTO_ACCAO_EFEITO <&> DE <&> ENUM_TORNAR

[2013.07.31: acto ou efeito de quem/que é CAUSADOR
PADRAO_PROP_CAUS_A ::= ACTO_ACCAO_EFEITO <&> DE <&> QUE_QUEM <&> é <&> ENUM_PROP_CAUS
PADRAO_PROP_CAUS_A ::= ACTO_ACCAO_EFEITO <&> CONJ <&> ACTO_ACCAO_EFEITO <&> DE <&> QUE_QUEM <&> é <&> ENUM_PROP_CAUS

[de causa PROPRIEDADE
PADRAO_PROP_CAUS_B ::= de <&> INST_CAUSADOR <&> ENUM_PROP_CAUS

[------------------------- Regras -------------------------]

ENUM_CAUS ::= SN_CAUSADOR
ENUM_CAUS ::= SN_CAUSADOR <&> VIRG <&> ENUM_CAUS
ENUM_CAUS ::= SN_CAUSADOR <&> CONJ <&> CAUSADOR_DE
ENUM_CAUS ::= SN_CAUSADOR <&> CONJ <&> VIRG <&> QUALQUERCOISA <&> VIRG <&> PDET <&> CAUSADOR_DE

SN_CAUSADOR ::= CAUSADOR_DE
SN_CAUSADOR ::= PRE_RELACIONADO <&> CAUSADOR_DE
SN_CAUSADOR ::= DET <&> SN_CAUSADOR
SN_CAUSADOR ::= S_PREP <&> SN_CAUSADOR
SN_CAUSADOR ::= TERCEIRO <&> SN_CAUSADOR
SN_CAUSADOR ::= MESMO <&> SN_CAUSADOR
SN_CAUSADOR ::= PRON_POSS <&> SN_CAUSADOR
SN_CAUSADOR ::= PRON_PESS <&> CAUSADOR_DE
SN_CAUSADOR ::= MODIFICADOR_CAUSADOR <&> CAUSADOR_DE
SN_CAUSADOR ::= PREP <&> NAO <&> SN_NAO_CAUS

ENUM_ACC_CAUS ::= SN_ACC_CAUS
ENUM_ACC_CAUS ::= SN_ACC_CAUS <&> VIRG <&> ENUM_ACC_CAUS
ENUM_ACC_CAUS ::= SN_ACC_CAUS <&> CONJ <&> SN_ACC_CAUS

SN_ACC_CAUS ::= ACCAO_QUE_CAUSA
SN_ACC_CAUS ::= DE <&> SN_ACC_CAUS
SN_ACC_CAUS ::= PRON_PESS <&> ACCAO_QUE_CAUSA
SN_ACC_CAUS ::= PRE_RELACIONADO <&> ACCAO_QUE_CAUSA

ENUM_PROP_CAUS ::= SN_PROP_CAUS
ENUM_PROP_CAUS ::= SN_PROP_CAUS <&> VIRG <&> ENUM_PROP_CAUS
ENUM_PROP_CAUS ::= SN_PROP_CAUS <&> CONJ <&> SN_PROP_CAUS

SN_PROP_CAUS ::= PROPRIEDADE_DE_ALGO_QUE_CAUSA

10 # ENUM_TORNAR ::= ACCAO_RESULTADO_DE
10 # ENUM_TORNAR ::= ACCAO_RESULTADO_DE <&> CONJ <&> RESULTADO_DE

[------------------------- Relacionados -------------------------]

HIPERONIMO_DE ::= <?>
MODIFICADOR_HIPERONIMO ::= MODIFICADOR_NOME

ACCAO_QUE_CAUSA ::= <?>
ACCAO_QUE_CAUSA ::= VERBO_TRANSITIVO <&> <?>
ACCAO_QUE_CAUSA ::= VERBO_TRANSITIVO <&> DET <&> <?>
ACCAO_QUE_CAUSA ::= VERBO_TRANSITIVO <&> NDET <&> <?>

VERBO_TRANSITIVO ::= VERBO_SER_INF
VERBO_TRANSITIVO ::= VERBO_ESTAR_INF
VERBO_TRANSITIVO ::= VERBO_TER_INF
VERBO_TRANSITIVO ::= VERBO_DEITAR_INF

ACCAO_RESULTADO_DE ::= VERBO_RESULTADO_INF <&> RESULTADO_DE
ACCAO_RESULTADO_DE ::= VERBO_RESULTADO_INF <&> DET <&> RESULTADO_DE
ACCAO_RESULTADO_DE ::= VERBO_TORNAR_INF <&> RESULTADO_DE
ACCAO_RESULTADO_DE ::= VERBO_TORNAR_INF <&> DET <&> RESULTADO_DE

CAUSADOR_DE ::= ENTIDADE_COMPLEXA
RESULTADO_DE ::= ENTIDADE_COMPLEXA

PROPRIEDADE_DE_ALGO_QUE_CAUSA ::= <?>