[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações de Finalidade (directa) em definições de nomes
[Permite ainda detectar também algumas relações de Hiperonímia

> ../terminais.txt
> ../uteis.txt
> ../verbos.txt
> ../padroes_finalidade.txt

[------------------------- Regras de alto nível -------------------------]

RAIZ ::= QUALQUERCOISA <&> PADRAO <&> QUALQUERCOISA
RAIZ ::= QUALQUERCOISA <&> PADRAO

RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA
RAIZ ::= PADRAO_INICIO

[------------------------- Padrões indicadores -------------------------]

100 # PADRAO_INICIO ::= HIPERONIMO_DE <&> PADRAO
100 # PADRAO_INICIO ::= MODIFICADOR_HIPERONIMO <&> HIPERONIMO_DE <&> PADRAO
100 # PADRAO_INICIO ::= HIPERONIMO_DE <&> MODIFICADOR_HIPERONIMO <&> PADRAO

PADRAO ::= PADRAO_FIN_NOME
PADRAO ::= PADRAO_ACC_FIN
PADRAO ::= PADRAO_PARA
PADRAO ::= PADRAO_COM_QUE_SE_FAZ

PADRAO_FIN_NOME ::= PADRAO_OBJECTIVO_A <&> DET <&> ENUM_FINS
PADRAO_FIN_NOME ::= PADRAO_USADO_PARA <&> DET <&> ENUM_FINS
[2013.08.02: e.g. 'para usar na cozinha' -- a relação não é bem a mesma, mas...
PADRAO_FIN_NOME ::= PADRAO_PARA_USAR_EM <&> ENUM_FINS
PADRAO_FIN_NOME ::= PADRAO_PARA_SERVIR_DE <&> ENUM_FINS

PADRAO_ACC_FIN ::= PADRAO_SERVIR_PARA <&> DET <&> ENUM_FINS

PADRAO_ACC_FIN ::= PADRAO_OBJECTIVO <&> ENUM_ACC_FIN
PADRAO_ACC_FIN ::= PADRAO_USADO_PARA <&> ENUM_ACC_FIN
PADRAO_ACC_FIN ::= PADRAO_SERVIR_PARA <&> ENUM_ACC_FIN

PADRAO_PARA ::= VIRG <&> PADRAO_PARA
PADRAO_PARA ::= PARA <&> DET <&> ENUM_FINS
PADRAO_PARA ::= PARA <&> SE <&> TER_OBTER <&> ENUM_FINS
PADRAO_PARA ::= PARA <&> SE <&> TER_OBTER <&> ENUM_FINS
[2013.08.09: aqui é outra relação
PADRAO_PARA ::= PARA <&> OBTENCAO <&> DE <&> ENUM_PRODUZIDO
[2013.08.09: e.g. 'uso em retroprojector'
PADRAO_PARA ::= PARA <&> UTILIZACAO <&> NDET <&> FINALIDADE_DE

[2013.08.09: neste caso nao deve extrair nada
100 # PADRAO_PARA ::= PARA <&> esse <&> efeito

PADRAO_PARA ::= PARA <&> ENUM_ACC_FIN
[2013.08.02: e.g. 'para poder jogar'
10 # PADRAO_PARA ::= PARA <&> VERBO_PODER_INF <&> ENUM_ACC_FIN



[2012.08.06
PADRAO_COM_QUE_SE_FAZ ::= com <&> QUE <&> se <&> ENUM_ACC_FIN

[ --> Vários problemas com a previsão da finalidade ser um verbo ou um nome :(

[------------------------- Enumerações -------------------------]

ENUM_FINS ::= INCLUI_FINS <&> VIRG <&> ENUM_FINS
ENUM_FINS ::= INCLUI_FINS <&> CONJ <&> INCLUI_FINS
ENUM_FINS ::= INCLUI_FINS

ENUM_ACC_FIN ::= INCLUI_ACC_FIN <&> VIRG <&> ENUM_ACC_FIN
ENUM_ACC_FIN ::= INCLUI_ACC_FIN <&> CONJ <&> INCLUI_ACC_FIN
ENUM_ACC_FIN ::= INCLUI_ACC_FIN

ENUM_PRODUZIDO ::= INCLUI_PRODUZIDO <&> VIRG <&> ENUM_PRODUZIDO
ENUM_PRODUZIDO ::= INCLUI_PRODUZIDO <&> CONJ <&> INCLUI_PRODUZIDO
ENUM_PRODUZIDO ::= INCLUI_PRODUZIDO

ENUM_NAO ::= <?>
ENUM_NAO ::= <?> <&> ENUM_NAO

[------------------------- Pré-relacionados -------------------------]

INCLUI_FINS ::= FAZ_SE_COM
INCLUI_FINS ::= PRE_RELACIONADO <&> FAZ_SE_COM
INCLUI_FINS ::= PARA <&> INCLUI_FINS
INCLUI_FINS ::= DET <&> FAZ_SE_COM
INCLUI_FINS ::= MESMO <&> FAZ_SE_COM
INCLUI_FINS ::= DET <&> MESMO <&> FAZ_SE_COM

INCLUI_ACC_FIN ::= FINALIDADE_DE
INCLUI_ACC_FIN ::= PRE_RELACIONADO <&> FINALIDADE_DE
INCLUI_ACC_FIN ::= PARA <&> FINALIDADE_DE
INCLUI_ACC_FIN ::= PRON_PESS <&> FINALIDADE_DE

INCLUI_PRODUZIDO ::= PRODUZIDO_POR
INCLUI_PRODUZIDO ::= DET <&> PRODUZIDO_POR

[instrumento para produzir, ... , um som -> devia dar para ignorar as vírgulas e o que está entre elas

FINALIDADE_DE ::= VERBO_INTERMEDIO_INF <&> PREP <&> ENTIDADE_COMPLEXA
FINALIDADE_DE ::= VERBO_INTERMEDIO_INF <&> FAZ_SE_COM
FINALIDADE_DE ::= VERBO_PRODUZIDO_INF <&> PREP <&> ENTIDADE_COMPLEXA
FINALIDADE_DE ::= VERBO_PRODUZIDO_INF <&> FAZ_SE_COM

FINALIDADE_DE ::= VERBO_FAZER_PRES <&> FAZ_SE_COM
FINALIDADE_DE ::= VERBO_FAZER_PRES <&> DET <&> FAZ_SE_COM

FINALIDADE_DE ::= <?> <&> DET <&> ENTIDADE_COMPLEXA
FINALIDADE_DE ::= VERBO_INF
FINALIDADE_DE ::= <?>
FINALIDADE_DE ::= VERBO_TRANSITIVO <&> ENTIDADE_COMPLEXA
FINALIDADE_DE ::= VERBO_TRANSITIVO <&> QUAL <&> ENTIDADE_COMPLEXA
FINALIDADE_DE ::= VERBO_TRANSITIVO <&> DET <&> ENTIDADE_COMPLEXA
[2013.08.09: e.g. 'fins ornamentais', é substantivo, mas a relação só é alterada para FAZ_SE_COM mais tarde
FINALIDADE_DE ::= OBJECTIVO <&> <?>
[e.g. 'fins de caridade'
FINALIDADE_DE ::= OBJECTIVO <&> de <&> <?>

[ ---- Outros --- ]

MODIFICADOR_FIM ::= certo
MODIFICADOR_FIM ::= determinado
MODIFICADOR_FIM ::= comum
MODIFICADOR_FIM ::= mesmo
MODIFICADOR_FIM ::= indevido
MODIFICADOR_FIM ::= específico
MODIFICADOR_FIM ::= útil
MODIFICADOR_FIM ::= diferente
MODIFICADOR_FIM ::= diferente <&> DO <&> <?>
MODIFICADOR_FIM ::= em <&> <?>

TER_OBTER ::= VERBO_TER_INF
TER_OBTER ::= VERBO_OBTER_INF

DIFERENTE_QUANT ::= MAIS_MENOS
DIFERENTE_QUANT ::= MAIOR_MENOR

UTILIZACAO ::= uso
UTILIZACAO ::= utilização

OBTENCAO ::= obtenção

[------------------------- Relacionados -------------------------]

MODIFICADOR_HIPERONIMO ::= MODIFICADOR_NOME
HIPERONIMO_DE ::= <?>

10 # FAZ_SE_COM ::= DIFERENTE_QUANT <&> FAZ_SE_COM
FAZ_SE_COM ::= ENTIDADE_COMPLEXA
FAZ_SE_COM ::= OBJECTIVO <&> <?>
FAZ_SE_COM ::= <?> <&> OBJECTIVO

PRODUZIDO_POR ::= ENTIDADE_COMPLEXA