[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações de Hiperonímia em definições de nomes

> ../terminais.txt
> ../uteis.txt
> ../verbos.txt
> ../cabecas_vazias.txt
> ../padroes_parte.txt

RAIZ ::= PADRAO_HIPERONIMIA
RAIZ ::= PADRAO_HIPERONIMIA <&> QUALQUERCOISA
50 # RAIZ ::= PADRAO_HIPERONIMIA_PARTE
50 # RAIZ ::= PADRAO_HIPERONIMIA_PARTE <&> QUALQUERCOISA
50 # RAIZ ::= PADRAO_HIPERONIMIA_ORIGEM
50 # RAIZ ::= PADRAO_HIPERONIMIA_ORIGEM <&> QUALQUERCOISA
100 # RAIZ ::= ENUM_SINONIMOS

[para nao apanhar sinonimos
ENUM_SINONIMOS ::= <?>
ENUM_SINONIMOS ::= <?> <&> VIRG <&> ENUM_SINONIMOS

[2013.07.31: para nao apanhar inicio de padroes parte, tipo "instrumento, composto de PARTE"
[repetido da gramática parte_de, para garantir que isoladas dão bons resultados
PADRAO_HIPERONIMIA_PARTE ::= HIPERONIMO_MODIFICADO <&> PADRAO_CONSTITUIDO <&> ENUM_OUTRA_REL
PADRAO_HIPERONIMIA_PARTE ::= HIPERONIMO_MODIFICADO <&> VIRG <&> PADRAO_CONSTITUIDO <&> ENUM_OUTRA_REL
[2013.08.01: o mesmo para local-origem
PADRAO_HIPERONIMIA_ORIGEM ::= HIPERONIMO_MODIFICADO <&> ORIGINARIO <&> DE <&> ENUM_OUTRA_REL
PADRAO_HIPERONIMIA_ORIGEM ::= HIPERONIMO_MODIFICADO <&> VIRG <&> ORIGINARIO <&> DE <&> ENUM_OUTRA_REL

[se tiver "de" indica hiperonímia, mas se tiver dos/das pode indicar meronímia
100 # PADRAO_HIPERONIMIA ::= INSTANCIA <&> DE_SINGULAR <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= MODIFICADOR_HIPERONIMO <&> INSTANCIA <&> DE_SINGULAR <&> ENUM_HIPERONIMOS
[2013.08.02: evitar extracções de inicio de padroes de outras relações
100 # PADRAO_HIPERONIMIA ::= PADRAO_HIPERONIMIA <&> VIRG <&> ORIGINARIO <&> ENUM_OUTRA_REL
100 # PADRAO_HIPERONIMIA ::= PADRAO_HIPERONIMIA <&> VIRG <&> PADRAO_CONSTITUIDO <&> ENUM_OUTRA_REL
100 # PADRAO_HIPERONIMIA ::= PADRAO_HIPERONIMIA <&> VIRG <&> PADRAO_PERTENCA <&> ENUM_OUTRA_REL

[um dos N HIPER
PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> NUMERAL <&> ENUM_HIPERONIMOS
[2013.07.31: um dos N nomes de/para HIPER
PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> NOME_PLURAL <&> DE_PARA <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> NOME_PLURAL <&> DE_PARA <&> DET <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> QUANT <&> NOME_PLURAL <&> DE_PARA <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> QUANT <&> NOME_PLURAL <&> DE_PARA <&> DET <&> ENUM_HIPERONIMOS
[um dos N nomes que se dá a HIPER -- nao ocorrem no DLP
[PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> NOME_PLURAL <&> QUE <&> SE <&> DAR <&> DET <&> ENUM_HIPERONIMOS
[PADRAO_HIPERONIMIA ::= NUMERAL <&> DE_PLURAL <&> NOME_PLURAL <&> QUANT <&> QUE <&> SE <&> DAR <&> DET <&> ENUM_HIPERONIMOS
[nome de HIPER
PADRAO_HIPERONIMIA ::= OUTRO_NOME <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= OUTRO_NOME <&> INSTANCIA_OU_COLECTIVO <&> DE <&> ENUM_HIPERONIMOS
PADRAO_HIPERONIMIA ::= OUTRO_NOME <&> DET <&> INSTANCIA_OU_COLECTIVO <&> DE <&> ENUM_HIPERONIMOS

[2013.08.01: para obrigar a lista de hiperónimos a terminar num 'que', quando existe
100 # PADRAO_HIPERONIMIA ::= PADRAO_HIPERONIMIA <&> QUE
100 # PADRAO_HIPERONIMIA ::= PADRAO_HIPERONIMIA <&> VIRG <&> QUE

PADRAO_HIPERONIMIA ::= ENUM_HIPERONIMOS <&> DE
PADRAO_HIPERONIMIA ::= ENUM_HIPERONIMOS <&> com
[acontece muito no DA
PADRAO_HIPERONIMIA ::= ENUM_HIPERONIMOS <&> VIRG

PADRAO_HIPERONIMIA ::= ENUM_HIPERONIMOS <&> PDET
PADRAO_HIPERONIMIA ::= ENUM_HIPERONIMOS <&> NDET
PADRAO_HIPERONIMIA ::= ENUM_HIPERONIMOS <&> QUE

ENUM_HIPERONIMOS ::= SN_HIPER <&> VIRG <&> ENUM_HIPERONIMOS
ENUM_HIPERONIMOS ::= SN_HIPER <&> CONJ <&> SN_HIPER
ENUM_HIPERONIMOS ::= SN_HIPER

SN_HIPER ::= HIPERONIMO_OU_VAZIO
SN_HIPER ::= DET <&> HIPERONIMO_OU_VAZIO
SN_HIPER ::= MODIFICADOR_HIPERONIMO <&> HIPERONIMO_OU_VAZIO

OUTRO_NOME ::= NOME <&> VULGAR <&> EXTENSIVO
OUTRO_NOME ::= NOME <&> VULGAR <&> EXTENSIVO <&> DET
OUTRO_NOME ::= NOME <&> QUE <&> SE <&> DAR <&> A

NOME ::= nome
NOME ::= designação
NOME ::= designativo

NOME_PLURAL ::= nomes
NOME_PLURAL ::= designações

VULGAR ::= <>
VULGAR ::= vulgar
VULGAR ::= comum
VULGAR ::= genérico
VULGAR ::= genérica

EXTENSIVO ::= extensivo <&> A
EXTENSIVO ::= extensiva <&> A
EXTENSIVO ::= referente <&> A
EXTENSIVO ::= DE

DAR ::= dá
DAR ::= dava

INSTANCIA_OU_COLECTIVO ::= INSTANCIA
INSTANCIA_OU_COLECTIVO ::= GRUPO
INSTANCIA_OU_COLECTIVO ::= CONJUNTO

[ --- Outras relações: tratados por outras gramáticas --- ]

[repetido da gramatica para PARTE_DE
ENUM_OUTRA_REL ::= <?> <&> ENUM_OUTRA_REL
ENUM_OUTRA_REL ::= <?>