[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações de Membro em definições de nomes

> ../terminais.txt
> ../uteis.txt
> ../padroes_parte.txt
> ../cabecas_vazias.txt

[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_TUDO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA
RAIZ ::= QUALQUERCOISA <&> PADRAO
RAIZ ::= QUALQUERCOISA <&> PADRAO <&> QUALQUERCOISA

[------------------------- Padrões PARTE -------------------------]

50 # PADRAO_TUDO ::= GRUPO <&> DE <&> ENUM_MEMBRO
50 # PADRAO_TUDO ::= CLASSE <&> DE <&> ENUM_MEMBRO
PADRAO_TUDO ::= PADRAO_INICIO

PADRAO_INICIO ::= GRUPO <&> DE <&> HIPERONIMO_MODIFICADO
PADRAO_INICIO ::= PADRAO_CONJUNTO

[se ocorrerem dois padrões:
[conjunto de vísceras que inclui o fígado
PADRAO_INICIO ::= PADRAO_INICIO <&> PADRAO
PADRAO_INICIO ::= PADRAO_INICIO <&> QUALQUERCOISA <&> PADRAO

PADRAO_INICIO ::= HIPERONIMO_MODIFICADO <&> PADRAO_MEMBRO
PADRAO_INICIO ::= HIPERONIMO_MODIFICADO <&> VIRG <&> PADRAO_MEMBRO
PADRAO_INICIO ::= PADRAO

PADRAO_CONJUNTO ::= CONJUNTO <&> DE <&> ENUM_MEMBRO
PADRAO_CONJUNTO ::= MODIFICADOR_NOME <&> CONJUNTO <&> DE <&> ENUM_MEMBRO
PADRAO_CONJUNTO ::= CONJUNTO <&> MODIFICADOR_NOME <&> DE <&> ENUM_MEMBRO

100 # PADRAO ::= GRUPO <&> DE <&> HIPERONIMO_MODIFICADO <&> QUALQUERCOISA <&> PADRAO
100 # PADRAO ::= GRUPO <&> DE <&> HIPERONIMO_MODIFICADO <&> PADRAO

PADRAO_INICIO ::= INSTANCIA <&> do <&> GRUPO <&> DE <&> ENUM_INCLUI
PADRAO_INICIO ::= INSTANCIA <&> DE_PLURAL <&> ENUM_INCLUI
PADRAO_INICIO ::= INSTANCIA <&> do <&> GRUPO <&> DE <&> ENUM_INCLUI

PADRAO ::= PADRAO_MEMBRO
[se ocorrerem dois padrões:
PADRAO ::= PADRAO_MEMBRO <&> PADRAO_MEMBRO
PADRAO ::= PADRAO_MEMBRO <&> QUALQUERCOISA <&> PADRAO_MEMBRO

PADRAO_MEMBRO ::= A <&> que <&> VERBO_PERTENCER_PRES <&> ENUM_MEMBRO
PADRAO_MEMBRO ::= que <&> PADRAO_INCLUI <&> ENUM_MEMBRO
PADRAO_MEMBRO ::= PADRAO_DQ_FAZ_PARTE <&> ENUM_MEMBRO
[retirada em 24.08.2011
[PADRAO_MEMBRO ::= INCLUINDO <&> ENUM_MEMBRO


[do grupo dos X
PADRAO_MEMBRO ::= DE <&> CONJUNTO <&> DE <&> ENUM_INCLUI
PADRAO_MEMBRO ::= DE <&> GRUPO <&> DE <&> ENUM_INCLUI
PADRAO_MEMBRO ::= DE <&> CLASSE <&> DE <&> ENUM_INCLUI

[da família...
50 # PADRAO_MEMBRO ::= DE_A <&> FAMILIA <&> DE_PLURAL <&> SN_INCLUI
50 # PADRAO_MEMBRO ::= DE_A <&> FAMILIA <&> DE_PLURAL <&> SN_INCLUI <&> VIRG <&> com <&> SN_PARTE
50 # PADRAO_MEMBRO ::= DE_A <&> FAMILIA <&> DE_PLURAL <&> SN_INCLUI <&> VIRG <&> com <&> parte <&> DE_O_A <&> SN_PARTE
[restrições para não aceitar "da família dos X, da América
50 # PADRAO_MEMBRO ::= DE_A <&> FAMILIA <&> DE_PLURAL <&> SN_INCLUI <&> VIRG <&> de <&> SN_PARTE_A

[negacao
PADRAO_MEMBRO ::= NAO <&> PADRAO_PERTENCA <&> ENUM_NAO

[------------------------- Padrões INCLUI -------------------------]

100 # PADRAO_INICIO ::= PADRAO_INCLUI <&> ENUM_INCLUI
[PADRAO ::= QUALQUERCOISA <&> PADRAO_INCLUI <&> ENUM_INCLUI

PADRAO_INICIO ::= HIPERONIMO_MODIFICADO <&> PADRAO_INCLUI <&> ENUM_INCLUI

PADRAO_INCLUI ::= MEMBRO <&> DE
50 # PADRAO_INCLUI ::= MEMBRO <&> DE <&> CONJUNTO <&> DE
50 # PADRAO_INCLUI ::= MEMBRO <&> DE <&> GRUPO <&> DE
50 # PADRAO_INCLUI ::= MEMBRO <&> DE <&> CLASSE <&> DE
50 # PADRAO_INCLUI ::= MEMBRO <&> DE <&> FAMILIA <&> DE
50 # PADRAO_INCLUI ::= MEMBRO <&> DE <&> INSTANCIA

PADRAO ::= PADRAO_PERTENCE
PADRAO_PERTENCE ::= que <&> VERBO_PERTENCER_PRES <&> A <&> ENUM_INCLUI
PADRAO_PERTENCE ::= PADRAO_PERTENCA <&> ENUM_INCLUI
PADRAO_PERTENCE ::= que <&> PADRAO_FAZ_PARTE <&> DE <&> ENUM_INCLUI

[------------------------- Regras -------------------------]

ENUM_MEMBRO ::= SN_MEMBRO <&> VIRG <&> ENUM_MEMBRO
ENUM_MEMBRO ::= SN_MEMBRO <&> CONJ <&> SN_MEMBRO
ENUM_MEMBRO ::= SN_MEMBRO

SN_MEMBRO ::= MEMBRO_DE
SN_MEMBRO ::= PRE_RELACIONADO <&> MEMBRO_DE
SN_MEMBRO ::= DET <&> SN_MEMBRO
SN_MEMBRO ::= DE <&> SN_MEMBRO
SN_MEMBRO ::= TUDO <&> SN_MEMBRO
SN_MEMBRO ::= PRON_POSS <&> SN_MEMBRO
SN_MEMBRO ::= ADJ_GENERICO <&> SN_MEMBRO
SN_MEMBRO ::= percentagem <&> SN_MEMBRO
SN_MEMBRO ::= MESMO <&> SN_MEMBRO

ENUM_INCLUI ::= SN_INCLUI <&> VIRG <&> ENUM_INCLUI
ENUM_INCLUI ::= SN_INCLUI <&> CONJ <&> SN_INCLUI
ENUM_INCLUI ::= SN_INCLUI

SN_INCLUI ::= INCLUI
SN_INCLUI ::= ADJ_GENERICO <&> INCLUI
[e.g. pertencente a duas espécies da família das X
100 # SN_INCLUI ::= ESPECIE <&> DE <&> SN_INCLUI
100 # SN_INCLUI ::= CONJUNTO <&> DE <&> INCLUI
100 # SN_INCLUI ::= GRUPO <&> DE <&> INCLUI
100 # SN_INCLUI ::= FAMILIA <&> DE <&> INCLUI
100 # SN_INCLUI ::= CLASSE <&> DE <&> INCLUI
100 # SN_INCLUI ::= membros <&> DE <&> INCLUI
SN_INCLUI ::= DET <&> SN_INCLUI
SN_INCLUI ::= DE <&> SN_INCLUI
SN_INCLUI ::= MESMO <&> SN_INCLUI
[2013.08.02: para evitar extracções tipo 'X de cujo' INCLUI Y
50 # SN_INCLUI ::= SN_INCLUI <&> CUJO
50 # SN_INCLUI ::= SN_INCLUI <&> DE <&> CUJO

ENUM_NAO ::= INCLUI_NAO_TODO <&> VIRG <&> ENUM_NAO
ENUM_NAO ::= INCLUI_NAO_TODO <&> CONJ <&> INCLUI_NAO_TODO
ENUM_NAO ::= INCLUI_NAO_TODO

INCLUI_NAO_TODO ::= NAO_INCLUI
INCLUI_NAO_TODO ::= ADJ_GENERICO <&> NAO_INCLUI
INCLUI_NAO_TODO ::= DET <&> INCLUI_NAO_TODO
INCLUI_NAO_TODO ::= CONJUNTO <&> DE <&> INCLUI_NAO_TODO
INCLUI_NAO_TODO ::= GRUPO <&> DE <&> INCLUI_NAO_TODO
INCLUI_NAO_TODO ::= CLASSE <&> DE <&> INCLUI_NAO_TODO
INCLUI_NAO_TODO ::= DE <&> INCLUI_NAO_TODO
INCLUI_NAO_TODO ::= MESMO <&> INCLUI_NAO_TODO

[mais restrito
SN_PARTE_A ::= PARTE_DE
SN_PARTE_A ::= ADJ_GENERICO <&> PARTE_DE

SN_PARTE ::= SN_PARTE_A
SN_PARTE ::= DET <&> SN_PARTE
SN_PARTE ::= ADJ_GENERICO <&> PARTE_DE

[--------------- Terminais --------------------]

MEMBRO_DE ::= ENTIDADE_COMPLEXA
MEMBRO_DE ::= espécies <&> <?>
PARTE_DE ::= ENTIDADE_COMPLEXA

INCLUI ::= ENTIDADE_COMPLEXA
[2013.08.02
INCLUI ::= reino <&> <?>
INCLUI ::= reino <&> DE <&> <?>
[INCLUI ::= GRUPO_FAMILIA <&> INCLUI

NAO_INCLUI ::= ENTIDADE_COMPLEXA