[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações Produtor (directa) em definições de nomes
[Permite ainda detectar também algumas relações de Hiperonímia

> ../terminais.txt
> ../verbos.txt
> ../uteis.txt
> ../padroes_produtor.txt


[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_INICIO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA
RAIZ ::= QUALQUERCOISA <&> PADRAO
RAIZ ::= QUALQUERCOISA <&> PADRAO <&> QUALQUERCOISA

[------------------------- Padrões indicadores -------------------------]

[podem ocorrer em qualquer sítio na definição
PADRAO ::= PADRAO_PRODUTOR_A

-100 # PADRAO ::= NAO <&> PADRAO <&> ENUM_NAO
-100 # PADRAO ::= NAO <&> é <&> PADRAO_PRODUTOR <&> ENUM_NAO

[só podem ocorrer no início da definição
PADRAO_INICIO ::= PADRAO_PRODUTOR_B
PADRAO_INICIO ::= PADRAO_PRODUTOR_INICIO

[...produzido por/pela... X - PRODUTOR_DE
100 # PADRAO_PRODUTOR_INICIO ::= HIPERONIMO_DE <&> PADRAO_PRODUTOR <&> ENUM_PROD
100 # PADRAO_PRODUTOR_INICIO ::= MODIFICADOR_HIPERONIMO <&> HIPERONIMO_DE <&> PADRAO_PRODUTOR <&> ENUM_PROD
100 # PADRAO_PRODUTOR_INICIO ::= HIPERONIMO_DE <&> MODIFICADOR_HIPERONIMO <&> PADRAO_PRODUTOR <&> ENUM_PROD

PADRAO_PRODUTOR_A ::= PADRAO_PRODUTOR <&> ENUM_PROD

[produto de X
PADRAO_PRODUTOR_B ::= INST_PRODUTO <&> DE <&> ENUM_PROD


[------------------------- Regras -------------------------]

ENUM_PROD ::= SN_PRODUTOR
ENUM_PROD ::= SN_PRODUTOR <&> VIRG <&> ENUM_PROD
ENUM_PROD ::= SN_PRODUTOR <&> CONJ <&> ENUM_PROD

SN_PRODUTOR ::= PRODUTOR_DE
SN_PRODUTOR ::= PRE_RELACIONADO <&> PRODUTOR_DE
SN_PRODUTOR ::= DET <&> SN_PRODUTOR
[SN_PRODUTOR ::= S_PREP <&> SN_PRODUTOR
SN_PRODUTOR ::= TERCEIRO <&> SN_PRODUTOR
SN_PRODUTOR ::= PRON_POSS <&> PRODUTOR_DE
SN_PRODUTOR ::= PRON_PESS <&> PRODUTOR_DE
SN_PRODUTOR ::= MODIFICADOR_PRODUTOR <&> PRODUTOR_DE
SN_PRODUTOR ::= PREP <&> NAO <&> SN_NAO

[------------------------- Relacionados -------------------------]

HIPERONIMO_DE ::= <?>
[HIPERONIMO_DE ::= <>
MODIFICADOR_HIPERONIMO ::= MODIFICADOR_NOME

PRODUTOR_DE ::= ENTIDADE_COMPLEXA