[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações de Causa (inversa) em definições de nomes
[Permite ainda detectar também algumas relações de Hiperonímia

> ../terminais.txt
> ../uteis.txt
> ../verbos.txt
> ../padroes_causa.txt


[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_INICIO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA
RAIZ ::= QUALQUERCOISA <&> PADRAO
RAIZ ::= QUALQUERCOISA <&> PADRAO <&> QUALQUERCOISA

[------------------------- Padrões indicadores -------------------------]

[podem ocorrer em qualquer sítio na definição
PADRAO ::= PADRAO_RESULTADO_B
PADRAO ::= PADRAO_RESULTADO_C

[só podem ocorrer no início da definição
[PADRAO_INICIO ::= PADRAO
PADRAO_INICIO ::= PADRAO_RESULTADO_A
PADRAO_INICIO ::= PADRAO_RESULTADO_D
100 # PADRAO_INICIO ::= PADRAO_COM_HIPER

PADRAO_COM_HIPER ::= PADRAO_HIPER <&> PADRAO
PADRAO_COM_HIPER ::= PADRAO_HIPER <&> PADRAO_RESULTADO_D

[o que causa X - RESULTADO_DE
PADRAO_RESULTADO_A ::= o <&> que <&> PADRAO_RESULTADO <&> ENUM_RES
-100 # PADRAO_RESULTADO_A ::= o <&> que <&> NAO <&> PADRAO_RESULTADO <&> ENUM_NAO_RES
[o que é novo e provoca X
PADRAO_RESULTADO_A ::= o <&> que <&> VERBO_PRES <&> <?> <&> CONJ <&> PADRAO_RESULTADO <&> ENUM_RES

PADRAO_RESULTADO_A ::= que <&> CONJ <&> PADRAO_RESULTADO_A
PADRAO_RESULTADO_A ::= que <&> CONJ <&> PADRAO_COM_HIPER
-100 # PADRAO_RESULTADO_A ::= o <&> que <&> NAO <&> PADRAO_RESULTADO <&> ENUM_NAO_RES

PADRAO_RESULTADO_B ::= que <&> PADRAO_RESULTADO <&> ENUM_RES
PADRAO_RESULTADO_B ::= que <&> PRON_PESS <&> PADRAO_RESULTADO <&> ENUM_RES
[que, comida em excesso, provoca disenteria
PADRAO_RESULTADO_B ::= que <&> VIRG <&> QUALQUERCOISA <&> VIRG <&> PADRAO_RESULTADO <&> ENUM_RES

-100 # PADRAO_RESULTADO_B ::= NAO <&> PADRAO_RESULTADO <&> ENUM_NAO_RES

PADRAO_RESULTADO_C ::= TER_COMO_RESULTADO <&> ENUM_RES

[causa de X

PADRAO_RESULTADO_D ::= INST_CAUSADOR <&> DE <&> ENUM_RES
PADRAO_RESULTADO_D ::= INST_CAUSADOR <&> CONJ <&> <?> DE <&> ENUM_RES

[recursividade para fazer algo tipo "que ou o que é o coiso ou o causador de X"
PADRAO_RESULTADO_D ::= DET <&> PADRAO_RESULTADO_D
PADRAO_RESULTADO_D ::= <?> <&> CONJ <&> PADRAO_RESULTADO_D
PADRAO_RESULTADO_D ::= o <&> que <&> VERBO_SER_PRES <&> PADRAO_RESULTADO_D
PADRAO_RESULTADO_D ::= que <&> CONJ <&> PADRAO_RESULTADO_D
[o que está na origem de X
PADRAO_RESULTADO_D ::= o <&> que <&> VERBO_ESTAR_PRES <&> NDET <&> PADRAO_RESULTADO_D

[------------------------- Regras -------------------------]

ENUM_RES ::= SN_RESULTADO
ENUM_RES ::= SN_RESULTADO <&> VIRG <&> ENUM_RES
ENUM_RES ::= SN_RESULTADO <&> CONJ <&> SN_RESULTADO

SN_RESULTADO ::= RESULTADO_DE
SN_RESULTADO ::= PRE_RELACIONADO <&> RESULTADO_DE
SN_RESULTADO ::= S_PREP <&> SN_RESULTADO
SN_RESULTADO ::= DET <&> SN_RESULTADO
SN_RESULTADO ::= PRON_POSS <&> RESULTADO_DE
SN_RESULTADO ::= MODIFICADOR_RESULTADO <&> SN_RESULTADO


[------------------------- Relacionados -------------------------]

MODIFICADOR_HIPERONIMO ::= MODIFICADOR_NOME
HIPERONIMO_DE ::= <?>

RESULTADO_DE ::= ENTIDADE_COMPLEXA