[Gramática usada para criar o PAPEL 3.2
[Hugo Gonçalo Oliveira, CISUC/Linguateca 2012

[Regras para a detecção de relações de Causa (inversa) nas definições de verbos

> ../terminais.txt
> ../uteis.txt
> ../verbos.txt
> ../padroes_causa.txt


[------------------------- Regras de alto nível -------------------------]

RAIZ ::= PADRAO_INICIO
RAIZ ::= PADRAO_INICIO <&> QUALQUERCOISA

[------------------------- Padrões indicadores -------------------------]

PADRAO_INICIO ::= PADRAO_RES_ACC

[causar X - RESULTADO_DA_ACCAO
PADRAO_RES_ACC ::= VERBO_RESULTADO_INF <&> ENUM_RES_ACC
-100 # PADRAO_RES_ACC ::= NAO <&> VERBO_RESULTADO_INF <&> ENUM_NAO_RES

PADRAO_RES_ACC ::= VERBO_TORNAR_INF <&> se <&> ENUM_RES_ACC
[tornar X -- X não pode ter determinantes antes
PADRAO_RES_ACC ::= VERBO_TORNAR_INF <&> RESULTADO_DA_ACCAO
PADRAO_RES_ACC ::= VERBO_TORNAR_INF <&> alguém <&> RESULTADO_DA_ACCAO
-100 # PADRAO_RES_ACC ::= VERBO_TORNAR_INF <&> DET <&> ENUM_NAO_RES

[nao existe "resultar em X"

[------------------------- Regras -------------------------]

ENUM_RES_ACC ::= SN_RESULTADO_ACC
ENUM_RES_ACC ::= SN_RESULTADO_ACC <&> VIRG <&> ENUM_RES_ACC
ENUM_RES_ACC ::= SN_RESULTADO_ACC <&> CONJ <&> SN_RESULTADO_ACC

SN_RESULTADO_ACC ::= RESULTADO_DA_ACCAO
SN_RESULTADO_ACC ::= PRE_RELACIONADO <&> RESULTADO_DA_ACCAO
SN_RESULTADO_ACC ::= DET <&> RESULTADO_DA_ACCAO
SN_RESULTADO_ACC ::= PRON_POSS <&> RESULTADO_DA_ACCAO
SN_RESULTADO_ACC ::= QUANT <&> RESULTADO_DA_ACCAO
SN_RESULTADO_ACC ::= DET <&> QUAL <&> RESULTADO_DA_ACCAO
SN_RESULTADO_ACC ::= QUAL <&> RESULTADO_DA_ACCAO


[------------------------- Relacionados -------------------------]

MANEIRA_DE_RESULTAR ::= ADVERBIO
MODIFICADOR_RESULTADO ::= MODIFICADOR_NOME
MODIFICADOR_RESULTADO_ACCAO ::= MODIFICADOR_NOME

RESULTADO_DA_ACCAO ::= <?>